Dialogue_VBLANK_Entrypoint:
	.SET_WINDOW_LCDC_E
	LD A, $mem_dungeon_flags
	BIT 3, A
	JR NZ, =.top_bar.enable

	.DISABLE_TOP_BAR

	LD A, $67
	LD $reg_lyc, A

	JR =.top_bar.end
	.top_bar.enable:

	.ENABLE_TOP_BAR

	LD A, $0a
	LD $reg_lyc, A
	.top_bar.end:

	LD A, $mem_current_mode
	CP $enum_dead_mode
	JR NZ, =.update_health_mana.end
		LD HL, $9d60
		LD A, $mem_bunny_health
		CALL =Print_8bit

		LD HL, $9d64
		LD A, $mem_bunny_mana
		CALL =Print_8bit
	.update_health_mana.end:


	CALL =Dialogue_Arrow_Animation
	CALL =Copy_Dialogue_Buffer
	CALL =Display_dialogue_cursor

	CALL $OAM_DMA_Transfer_routine

	; LYC
	LD A, $0a
	LD $reg_lyc, A
	.ENABLE_LYC_INTERRUPT
	.RESET_INTERRUPTS
	EI

	CALL =Pad_Button_Check

	CALL =Update_Blinking_Counter
	CALL =Update_Animation_Steps
	CALL =Open_dialogue_on_dungeon_menu_mode
	CALL =Move_dialogue_cursor
	CALL =Check_dialogue_action

	LD A, $00
	LD $mem_oam_buffer_low, A
	CALL =Display_Animation_List
	CALL =Display_Entities

	LD A, $mem_loop_frame_timer
	INC A
	LD $mem_loop_frame_timer, A

	LD A, $mem_sound_flags
	BIT 6, A
	JR Z, =.Music_Play
	LD A, $mem_display_flag
	BIT 2, A
	JR NZ, =.Sound_Effects_Play
	BIT 4, A
	JR NZ, =.Sound_Effects_Play
	LD A, $mem_sound_flags
	RES 6, A
	SET 0, A
	LD $mem_sound_flags, A
	CALL =Start_Music
	JR =.Sound_Effects_Play

	.Music_Play:
	CALL =Play_Music
	.Sound_Effects_Play:
	CALL =Play_Sound_Effect

	.ENABLE_VBLANK_INTERRUPTS
	RETI