1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
|
Initialize_Objects:
LD A, $mem_map_loading_flags
OR $01
LD $mem_map_loading_flags, A
LD HL, $mem_object_list
LD BC, $0080
CALL =bff
LD HL, $mem_object_list
CALL =Spawn_stairs
CALL =Spawn_carrot
CALL =Spawn_leaf
RET
Find_Free_Object_slot: ; Return free object slot in HL ($80 if none is found)
LD HL, $mem_object_list
.loop:
LD A, $ff
CP (HL)
RET Z
LD A, L
ADD $08
LD L, A
CP $80
JR NZ, =.loop
RET
Spawn_object_in_random_room_avoid_bunny: ; Object tile in A, Object jump table id in E, Object pointer in HL
LD (HL+), A
.retry:
CALL =.retry.entrypoint
JR =.retry
.retry.entrypoint:
LD A, $mem_bunny_current_room_idx
CALL =Pick_Random_Room_Avoid_A
JR =Spawn_object_in_random_room.place_object_in_room_A
Spawn_object_in_random_room: ; Object tile in A, Object jump table id in E, Object pointer in HL
LD (HL+), A
.retry:
CALL =.retry.entrypoint
JR =.retry
.retry.entrypoint:
LD A, $mem_number_of_rooms
CALL =RNG_Bound
.place_object_in_room_A:
SLA A
SLA A
ADD low($mem_room_list)
LD C, A
LD B, high($mem_room_list)
LD A, (BC)
LD D, A
INC BC
LD A, (BC)
INC A
CALL =RNG_Bound
ADD D
LD (HL+), A
INC BC
LD A, (BC)
LD D, A
INC BC
LD A, (BC)
INC A
CALL =RNG_Bound
ADD D
LD (HL), A
LD C, (HL)
DEC HL
LD B, (HL)
CALL =Is_Collisionable
CP $00
RET NZ
ADD SP, $02
CALL =Check_other_object_collision
CP $00
RET NZ
INC HL
INC HL
LD (HL), E
LD A, L
AND $f8
ADD $08
LD L, A
RET
Check_other_object_collision: ; Object in HL (with only sprite x & y set), will be zeroed on collision and A will be 1 on return
LD A, L
AND $f8
ADD $01
LD L, A
LD BC, $mem_object_list
Object_check_collisions.loop:
LD A, (BC)
CP $00
JR Z, =Object_check_collisions.loop.next
INC BC
LD A, C
CP L
JR Z, =Object_check_collisions.loop.next
LD A, (BC)
CP (HL)
JR NZ, =Object_check_collisions.loop.next
INC BC
INC HL
LD A, (BC)
CP (HL)
JR NZ, =Object_check_collisions.loop.next
DEC HL
DEC HL
XOR A
LD (HL+), A
LD (HL+), A
LD (HL), A
DEC HL
DEC HL
LD A, $01
RET
Object_check_collisions.loop.next:
LD A, L
AND $f8
ADD $01
LD L, A
LD A, C
AND $f8
ADD $08
LD C, A
CP $80
JR NZ, =Object_check_collisions.loop
LD A, $00
RET
Spawn_stairs:
LD A, $60
LD E, $01
JP =Spawn_object_in_random_room_avoid_bunny
Spawn_carrot:
LD A, $64
LD E, $02
JP =Spawn_object_in_random_room
Spawn_leaf:
LD A, $68
LD E, $03
JP =Spawn_object_in_random_room
Object_Interaction_Jump_table:
; 00
RET
NOP
NOP
NOP
; 01
JP =Stairs_Action
NOP
; 02
JP =Heal_Action
NOP
; 03
JP =Restore_EP_Action
NOP
; 04
JP =Heal_Attack_Box_Action
NOP
; 05
JP =Freeze_Attack_Box_Action
NOP
; 06
JP =Earcopter_Attack_Box_Action
NOP
; 07
JP =Fimsh_Attack_Box_Action
NOP
Stairs_Action:
LD A, $enum_dungeon_generation_mode
LD $mem_current_mode, A
LD $mem_requested_mode, A
CALL =Update_VBlank_Handler
LD A, $mem_floor_count
INC A
DAA
JR C, =.skip_update_floor_count
LD $mem_floor_count, A
LD A, $mem_floor_count_bin
INC A
LD $mem_floor_count_bin, A
.skip_update_floor_count:
LD A, $mem_sound_flags
BIT 1, A
CALL NZ, =Reset_Music_Channel1
LD A, $mem_sound_flags
BIT 2, A
CALL NZ, =Reset_Music_Channel2
LD A, $mem_sound_flags
BIT 3, A
CALL NZ, =Reset_Music_Channel3
LD A, $mem_sound_flags
BIT 4, A
CALL NZ, =Reset_Music_Channel4
LD A, $mem_sound_flags
AND 0b11000001
LD $mem_sound_flags, A
LD A, $00
LD $mem_sound_effect_frame_count, A
LD A, $ff
LD ($mem_sound_effect_pc), A
.SET_SOUND_EFFECT =_sound_effect_Next_Floor
RET
Heal_Action:
LD A, $mem_bunny_health
ADD $03
DAA
CP $20
JR C, =.Set_health
LD A, $20
.Set_health:
LD $mem_bunny_health, A
PUSH BC
LD A, $mem_bunny_x
LD B, A
LD A, $mem_bunny_y
LD C, A
LD A, $01
PUSH DE
LD E, $20
LD D, $00
CALL =Try_Launch_Animation
POP DE
POP BC
.SET_SOUND_EFFECT =_sound_effect_Heal
LD (HL), $00
RET
Heal_Attack_Box_Action:
LD (HL), $00
.START_SCRIPT =.Script
LD A, $enum_dungeon_dialogue_mode
LD $mem_requested_mode, A
LD $mem_current_mode, A
LD A, $mem_bunny_direction
RES 3, A
LD $mem_bunny_direction, A
LD A, $00
LD $mem_bunny_animation, A
LD A, $mem_map_loading_flags
SET 5, A
RES 3, A
LD $mem_map_loading_flags, A
RET
.Script:
.LEARN_ATTACK $02
.END
Freeze_Attack_Box_Action:
LD (HL), $00
.START_SCRIPT =.Script
LD A, $enum_dungeon_dialogue_mode
LD $mem_requested_mode, A
LD $mem_current_mode, A
LD A, $mem_bunny_direction
RES 3, A
LD $mem_bunny_direction, A
LD A, $00
LD $mem_bunny_animation, A
LD A, $mem_map_loading_flags
SET 5, A
RES 3, A
LD $mem_map_loading_flags, A
RET
.Script:
.LEARN_ATTACK $03
.END
Earcopter_Attack_Box_Action:
LD (HL), $00
.START_SCRIPT =.Script
LD A, $enum_dungeon_dialogue_mode
LD $mem_requested_mode, A
LD $mem_current_mode, A
LD A, $mem_bunny_direction
RES 3, A
LD $mem_bunny_direction, A
LD A, $00
LD $mem_bunny_animation, A
LD A, $mem_map_loading_flags
SET 5, A
RES 3, A
LD $mem_map_loading_flags, A
RET
.Script:
.LEARN_ATTACK $04
.END
Fimsh_Attack_Box_Action:
LD (HL), $00
.START_SCRIPT =Fimsh_Dialogue_Script
LD A, $enum_dungeon_dialogue_mode
LD $mem_requested_mode, A
LD $mem_current_mode, A
LD A, $mem_bunny_direction
RES 3, A
LD $mem_bunny_direction, A
LD A, $00
LD $mem_bunny_animation, A
LD A, $mem_map_loading_flags
SET 5, A
RES 3, A
LD $mem_map_loading_flags, A
RET
Restore_EP_Action:
LD A, $mem_bunny_mana
ADD $05
DAA
JR NC, =.Set_mana
LD A, $99
.Set_mana:
LD $mem_bunny_mana, A
PUSH BC
LD A, $mem_bunny_x
LD B, A
LD A, $mem_bunny_y
LD C, A
LD A, $01
PUSH DE
LD E, $20
LD D, $00
CALL =Try_Launch_Animation
POP DE
POP BC
.SET_SOUND_EFFECT =_sound_effect_Heal
LD (HL), $00
RET
Display_Object:
LD A, $mem_display_flag
BIT 5, A
RET NZ
LD HL, $mem_object_list
LD A, $mem_object_load_counter
INC A
AND $0f
LD $mem_object_load_counter, A
SLA A
SLA A
SLA A
AND $f8
LD L, A
LD A, (HL)
CP $FF
RET Z
LD C, A
CP $00
JR NZ, =.skip_remove_object_after_display
LD (HL), $FF
.skip_remove_object_after_display:
INC HL
LD A, (HL+)
ADD $80
LD D, A
LD A, $mem_viewport_x
SUB $83
CP D
RET NC
ADD $0e
CP D
RET C
LD A, D
SUB $80
LD D, A
LD A, (HL+)
ADD $80
LD B, A
LD A, $mem_viewport_y
SUB $83
CP B
RET NC
ADD $0e
CP B
RET C
LD A, B
SUB $80
LD B, A
LD A, C
CP $00
JR Z, =Display_Objects.Nothing
LD A, D
CALL =Construct_Tile_Address
LD A, C
LD (DE), A
INC E
INC C
LD A, C
LD (DE), A
INC C
LD A, E
XOR $21
LD E, A
LD A, C
LD (DE), A
INC C
INC E
LD A, C
LD (DE), A
RET
Display_Objects.Nothing:
LD A, D
LD $mem_additional_loading_block_x, A
LD A, B
LD $mem_additional_loading_block_y, A
LD A, $mem_display_flag
SET 6, A
LD $mem_display_flag, A
RET
Load_Objects:
CALL =Display_Object
CALL =Display_Object
CALL =Display_Object
CALL =Display_Object
CALL =Display_Object
CALL =Display_Object
CALL =Display_Object
CALL =Display_Object
CALL =Display_Object
CALL =Display_Object
CALL =Display_Object
CALL =Display_Object
CALL =Display_Object
CALL =Display_Object
CALL =Display_Object
CALL =Display_Object
RET
Object_Interactions_Check:
LD A, $mem_moving_animation_step
CP $00
JR NZ, =.End
LD A, $mem_map_loading_flags
BIT 1, A
JR Z, =.End
RES 1, A
LD $mem_map_loading_flags, A
LD HL, $mem_object_list
LD A, $mem_bunny_x
LD C, A
LD A, $mem_bunny_y
LD B, A
.loop:
LD A, (HL+)
CP $00
JR Z, =.next
CP $FF
JR Z, =.next
LD A, (HL+)
CP C
JR NZ, =.next
LD A, (HL+)
CP B
JR NZ, =.next
LD E, (HL)
PUSH BC
; So we have HL set to the object pointer
LD A, L
AND $f8
LD L, A
LD BC, =Object_Interaction_Jump_table
LD A, E
.JUMP_TABLE
POP BC
.next:
LD A, L
AND $f8
ADD $08
LD L, A
CP $80
JR NZ, =.loop
.End:
RET
|
